用bat实现的自动关机的代码

一般情况下我们都是使用shutdown来实现关机与重启

用法: shutdown [/i | /l | /s | /r | /a | /p | /h | /e] [/f]
[/m \\computer][/t xxx][/d [p:]xx:yy [/c "comment"]]

没有参数 显示帮助。这与键入 /? 是一样的
/? 显示帮助。这与不键入任何选项是一样的
/i 显示图形用户界面(GUI)。
这必须是第一个选项
/l 注销。这不能与 /m 或 /d 选项一起使用
/s 关闭计算机
/r 关闭并重启动计算机
/a 放弃系统关闭。
这只能在超时过程中使用
/p 关闭本地计算机,没有超时或警告。
这只能与 /d 选项一起使用
/h 休眠本地计算机。
这只能与 /f 选项一起使用
/e 将计算机的意外关闭原因记入文档
/m \\computer 指定目标计算机
/t xxx 设置关闭前的超时为 xxx 秒。
有效范围是 0-600,默认为 30
/c "comment" 重启动或关闭的原因的注释。
最大允许 127 个字符
/f 强制正在运行的应用程序关闭而不事先警告用户
/d [p:]xx:yy 提供重启动或关闭的原因
p 表明重启动或关闭是计划内的
xx 是主要原因号(小于 256 的正整数)
yy 是次要原因号(小于 65536 的正整数)

重启
shutdown /r /f

关机
shutdown /s /f

先来个简单功能版本的



代码如下:

@echo off
mode con lines=25
title 定时关机
color 1f
cls
echo.
echo.
echo.
echo.
echo              时间使用24小时制(如2:15、12:00),可以输入多个时间点
echo.
echo                           多个时间点用空格分隔
echo.
echo.
echo ━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━
echo.
set times=
set /p times=                     请输入关机时间:
:: 以下语句实现每个星期的每一天指定时间关机
:: 如果要换成每个月的某几天,请改字母为数字,并用逗号分隔
:: 以下代码没有错误检测语句,输入时间的时候务必按照指定格式输入
:: 可以用在CMD窗口用at命令来查看计划任务
if not "%times%"=="" for %%i in (%times%) do (
    at %%i /every:M,T,W,Th,F,S,Su shutdown -s
)

下面是多功能版的,适合学习bat的朋友


代码如下:

@ECHO off
TITLE 自动关机程序 作者:廖晓青
:start
CLS
COLOR 1f
rem 使用COLOR命令对控制台输出颜色进行更改
MODE con: COLS=41 LINES=18
rem MODE语句为设定窗体的宽和高
set tm1=%time:~0,2%
set tm2=%time:~3,2%
set tm3=%time:~6,2%
ECHO %date% %tm1%点%tm2%分%tm3%秒
ECHO =========================================
ECHO 请选择要进行的操作,然后按回车
ECHO ───────────────
ECHO.
ECHO 1. 定时关机
ECHO 2. 倒计时关机
ECHO 3. 删除定时关机任务
ECHO 4. 查看任务状态
ECHO 5. 刷新当前时间
ECHO 6. 重新启动
ECHO 7. 锁定计算机
ECHO 8. 注销
ECHO 9. 退出
ECHO.

:cho
SET Choice=
SET /P Choice=选择:
rem 设定变量"Choice"为用户输入的字符
IF NOT "%Choice%"=="" SET Choice=%Choice:~0,1%
rem 如果输入大于1位,取第1位,比如输入132,则返回值为1
ECHO.
IF /I "%Choice%"=="1" GOTO SetHour
IF /I "%Choice%"=="2" GOTO outtime
IF /I "%Choice%"=="3" GOTO delAt
IF /I "%Choice%"=="4" GOTO view
IF /I "%Choice%"=="5" GOTO start
IF /I "%Choice%"=="6" GOTO restart
IF /I "%Choice%"=="7" GOTO lock
IF /I "%Choice%"=="8" GOTO logoff
IF /I "%Choice%"=="9" GOTO end
rem 为避免出现返回值为空或含空格而导致程序异常,需在变量外另加双引号
rem 注意,IF语句需要双等于号
rem 如果输入的字符不是以上数字,将返回重新输入
ECHO 选择无效,请重新输入
ECHO.
GOTO cho

:SetHour
CLS
ECHO.
SET ask=
SET /p ask=是否设定为每天执行关机命令(y/n):
IF NOT "%ask%"=="" SET ask=%ask:~0,1%
IF /I "%ask%"=="y" GOTO yes
IF /I "%ask%"=="n" GOTO no
GOTO SetHour

:yes
ECHO 请指定24小时制式时间,格式为 小时:分钟
SET shutdowntime=
SET /p shutdowntime=输入:
at %shutdowntime% /every:M,T,W,Th,F,S,Su tsshutdn 0 /delay:0 /powerdown >nul
rem 设定为每周的星期一至星期日,即为每天
IF NOT errorlevel 1 GOTO ok
rem 如果输入正确,就执行ok段的语句
ECHO %shutdowntime% 不是标准的时间格式,请重新输入
ECHO.
GOTO yes

:no
ECHO 请指定24小时制式时间,格式为 小时:分钟
SET shutdowntime=
SET /p shutdowntime=输入:
at %shutdowntime% tsshutdn 0 /delay:0 /powerdown >nul
IF NOT errorlevel 1 GOTO ok
ECHO %shutdowntime% 不是标准的时间格式,请重新输入
ECHO.
GOTO no

:ok
ECHO.
SET h=%shutdowntime:~1,1%
SET ah=%shutdowntime:~0,1%
SET am=%shutdowntime:~2,2%
SET bh=%shutdowntime:~0,2%
SET bm=%shutdowntime:~3,2%
IF "%h%"==":" (
SET HM=%ah%时%am%分
) ELSE (
SET HM=%bh%时%bm%分)
rem 如果输入h:mm则HM=h时mm分,否则HM=hh时mm分
IF /I "%ask%"=="y" ECHO 系统将于每天的%HM%关闭
IF /I "%ask%"=="n" ECHO 系统将于%HM%关闭
ECHO 设定完毕! 按任意键继续...
PAUSE >nul
GOTO start

:outtime
CLS
ECHO.
ECHO 请输入倒计时秒数
ECHO ────────
ECHO (设定后要取消,单击"确定"后按Ctrl+C键两次)
SET timed=
SET /p timed=输入:
tsshutdn %timed% /delay:0 /powerdown >nul
IF not errorlevel 1 GOTO ok
ECHO %timed% 是无效的关机时间,请重新输入
ECHO.
GOTO outtime

:delAt
cls
echo.
at /del /y
echo 定时关机任务已取消,按任意键继续...
pause >nul
GOTO start

:view
MODE con: COLS=85 LINES=18
COLOR 70
ECHO.
at
ECHO 按任意键继续...
PAUSE >nul
GOTO start

:restart
shutdown -r -t 0

:lock
rundll32.exe user32.dll,LockWorkStation
goto start

:logoff
logoff

:end
exit

(0)

相关推荐

  • emule自动关机脚本

    dir="E:\Temp" Set fso=CreateObject("Scripting.FileSystemObject") cmd="shutdown -s -f -t 60" Set ws=WScript.CreateObject("WScript.Shell") Wscript.Echo "emule自动关机脚本已运行--" count=0 do until count<-1 chksize

  • vbs实现的eMule电驴自动关机脚本代码

    Set fso = CreateObject("Scripting.FileSystemObject") Set ws = WScript.CreateObject("WScript.Shell") Count = 0 Do Until Count< -1     chksize = fso.GetFolder("C:\Program Files\eMule\Temp").Size     If chksize = 0 Then      

  • 用批处理实现电脑自动关机

    虽然大家学过了一些Windows的命令,但用批处理来与用户交互并实现自动关机可能还没有试过吧.自己做一个关机程序,感觉可不一样.下面我们就利用Windows 的批处理脚本,来实现自动关机的功能,程序不算复杂,功能可一点都不少哦!本程序在Windows xp/2000/2003环境下测试通过. 第一步: 打开记事本,输入下面的文字(以rem开头的语句是注释,可以不必输入). 复制代码 代码如下: @echo off  title 自动关机程序 作者:青剑  rem 这里改成你的名字好了  colo

  • bat定时自动关机,bat自动结束任务关闭程序,dos自动结束程序后关机

    自动结束程序 ntsd 是一条dos命令,功能是用于结束一些常规下结束不了的死进程.用法为打开cmd 后输入以下命令就可以结束进程:方法一:利用进程的PID结束进程命令格式:ntsd -c q -p pid 命令范例: ntsd -c q -p 1332 (结束explorer.exe进程)范例详解:explorer.exe的pid为1332,但是如何获取进程的pid呢?在CMD下输入TASKLIST就可以获取当前任务管理器所有进程的PID方法二:利用进程名结束进程命令格式:ntsd -c q

  • VBS 断网后自动关机30秒后

    复制代码 代码如下: Dim Wsh,objWMIService,colMonitoredEvents Set Wsh = WScript.CreateObject("WScript.Shell") Set objWMIService = GetObject("winmgmts:\. ootwmi") Set colMonitoredEvents = objWMIService.ExecNotificationQuery("Select * from MS

  • 可以实现系统自动关机的批处理

    @ECHO off TITLE 自动关机程序 作者:廖晓青 :start CLS COLOR 1f rem 使用COLOR命令对控制台输出颜色进行更改 MODE con: COLS=41 LINES=18 rem MODE语句为设定窗体的宽和高 set tm1=%time:~0,2% set tm2=%time:~3,2% set tm3=%time:~6,2% ECHO %date% %tm1%点%tm2%分%tm3%秒 ECHO ===============================

  • 可以定时自动关机的vbs脚本

    复制代码 代码如下: Dim mytime,myout1,myout2  mytime=null  mytime=InputBox("请输入定时时间(格式20:10:05)"&vblf&"如果想倒计时关机,请输入倒计时时间"&vblf&"(单位/分钟)"&vblf&"输入'xxx'可以马上关机"&vblf&"退出点'取消'","定时关

  • 用bat实现的自动关机的代码

    一般情况下我们都是使用shutdown来实现关机与重启 用法: shutdown [/i | /l | /s | /r | /a | /p | /h | /e] [/f] [/m \\computer][/t xxx][/d [p:]xx:yy [/c "comment"]] 没有参数 显示帮助.这与键入 /? 是一样的 /? 显示帮助.这与不键入任何选项是一样的 /i 显示图形用户界面(GUI). 这必须是第一个选项 /l 注销.这不能与 /m 或 /d 选项一起使用 /s 关闭计算

  • BAT加密工具 EncryBat 非编译型bat批处理加密方案与代码

    bat文件虽然好用,但安全性太脆弱 随便什么人都可以打开查看,甚至修改其中内容 有没有什么办法不把.bat转换成.exe或.com之类,仍是.bat文件 但别人无法查看并修改其中内容??? 有没有什么自我加密之类的呢? 高手给个解决的思路吧 目前讨论的方案如下: 1.在批处理代码插入Unicode特征串的方案 对记事本等使用IsTextUnicode函数识别编码类型的程序有效 对type/edit/EditPlus/UltraEdit等不使用IsTextUnicode函数的程序无效 2.给批处理

  • windows下直接点击startup.bat启动tomcat服务示例代码

    在XP上明明已经安装了JDK1.5并设置好了JAVA_HOME,可偏偏Tomcat在启动过程中找不到. 报错信息如下:Neither the JAVA_HOME nor the JRE_HOME environment variable is defined At least one of these environment variable is needed to run this program;提示找不到java_home各jre_home路径,何解? 原因不知道了,下面来看解决办法:

  • 批处理BAT实现正弦曲线和抛物线代码

    先奉上正弦曲线的: @echo off&setlocal enabledelayedexpansion ( :loop for %%i in (30 46 55 59 60 59 55 46 30 14 5 1 0 1 5 14) do ( for /l %%j in (1 1 %%i) do ( set "str=!str! " ) echo !str!#&set str= for /l %%i in (1 1 600) do qdj 2>nul ) goto

  • C语言system 自动关机函数代码

    ime_t t; time(&t); 函数名称: time 函数原型: time_t time(time_t *timer) 函数功能: 得到机器的日历时间或者设置日历时间 函数返回: 机器日历时间 参数说明: timer=NULL时得到机器日历时间,timer=时间数值时,用于设置日历时间,time_t是一个long类型 所属文件: <time.h> #include <time.h> #include <stdio.h> #include <dos.h

  • bat批处理位运算实例代码

    发现很多新手对于批处理中set/a的位运算的概念有点模糊,我也是,什么"异.或.与.逻辑移位",看的云里雾里,头脑发胀,于是就有了下面的代码. @echo off if "%~1" equ "" exit/b :begin setlocal enabledelayedexpansion set "Var=0123456789ABCDEF" set/p number=Input: if /i "%number%&quo

  • BAT批处理之文件与文件夹操作代码(附xcopy命令详解)

    批处理中的文件.文件夹操作,xcopy命令的用法. 一,建bat文件自动执行复制,删除命令. 例1:复制cd.dll文件至windows\system32的bat文件内容: 复制代码 代码如下: copy cd.dll %windir%\system32 例2:卸载windows\system32目录中的cd.dll,即把上面复制的文件删除: 复制代码 代码如下: del %windir%\system32\cd.dll 例3:删除download文件夹中的文件,例子如下: 复制代码 代码如下:

  • 写一个bat批处理文件启动windows进程和延时关闭的代码

    前些天领导让我们在网站上投票提高他的排名,可是每人投一票才100多票.过了几天领导问我会不会做个刷票程序,提高排名,我说可以试试,研究了一天,终于做出来了,兴奋的我一晚上没睡着.现在拿出来分享一下. 说白了我做的其实就是个批处理文件,批处理扩展名为.bat,其实那个投票页面只是用session去控制是否投票,众所周知,session变量在IE关闭后就会自动消失,重新打开页面时又会创建一个新的连接,这就可以重复投了,这个页面是用的AJAX,我找到ajax所在的JS,把它的真正的投票页面找出来,把I

  • 清理IE和使用历史记录的bat代码

    复制代码 代码如下: @echo off title: IE temporary file deleter echo 正在 清除Internet临时文件 ............ RunDll32.exe InetCpl.cpl,ClearMyTracksByProcess 8 echo 清除Cookies RunDll32.exe InetCpl.cpl,ClearMyTracksByProcess 2 echo 清除历史记录 RunDll32.exe InetCpl.cpl,ClearMyT

随机推荐