易语言隐藏窗口图文教程

本经验可以帮你的软件添加像气QQ一样的伸缩窗口

新建一个Windows窗口程序

双击启动窗口,输入代码:

.版本 2

.支持库 spec

.程序集 窗口程序集1

.程序集变量 原窗口, 整数型

.程序集变量 停靠, 整数型, , , 1左,2上,3右,0为不

.程序集变量 正在收放, 整数型, , , 1收,2放

.程序集变量 计数, 整数型

.程序集变量 已收起, 逻辑型

.程序集变量 时钟, 整数型

.程序集变量 步进长度, 整数型, , , 新加的

.程序集变量 最小尺寸, 整数型, , , 新加的

.子程序 __启动窗口_创建完毕

' 本程序严格按照比赛要求,只限制左,上,右窗口移动和停靠,且只和鼠标在窗口停留或离开后1秒后才有动作-borisc

原窗口 = 设置窗口信息_ (取窗口句柄 (), #GWL_WNDPROC, 到整数 (&处理))

读回窗口位置 ()

步进长度 = 15

最小尺寸 = 5

.子程序 读回窗口位置, , , 移植_

.局部变量 配置文件名, 文本型

配置文件名 = 取运行目录 () + “\窗口位置.INI”

_启动窗口.高度 = 到数值 (读配置项 (配置文件名, “WINDOW”, “高度”, 到文本 (取屏幕高度 () ÷ 2)))

_启动窗口.宽度 = 到数值 (读配置项 (配置文件名, “WINDOW”, “宽度”, 到文本 (取屏幕宽度 () ÷ 4)))

_启动窗口.左边 = 到数值 (读配置项 (配置文件名, “WINDOW”, “左边”, 到文本 (取屏幕宽度 () ÷ 2)))

_启动窗口.顶边 = 到数值 (读配置项 (配置文件名, “WINDOW”, “顶边”, “0”))

.如果真 (_启动窗口.左边 > 取屏幕宽度 () - 30)

 _启动窗口.左边 = (取屏幕宽度 () - _启动窗口.宽度) ÷ 2

.如果真结束

.如果真 (_启动窗口.左边 < 0)

 _启动窗口.左边 = 0

.如果真结束

.如果真 (_启动窗口.顶边 > 取屏幕高度 () - _启动窗口.高度)

 _启动窗口.顶边 = 取屏幕高度 () - _启动窗口.高度

.如果真结束

.如果真 (_启动窗口.顶边 < 0)

 _启动窗口.顶边 = 0

.如果真结束

调试输出 (“_启动窗口.”, _启动窗口.左边, _启动窗口.顶边, _启动窗口.高度, _启动窗口.宽度)

.子程序 将被销毁保存位置, , , 移植_

.局部变量 配置文件名, 文本型

配置文件名 = 取运行目录 () + “\窗口位置.INI”

写配置项 (配置文件名, “WINDOW”, “左边”, 到文本 (_启动窗口.左边))

写配置项 (配置文件名, “WINDOW”, “顶边”, 到文本 (_启动窗口.顶边))

写配置项 (配置文件名, “WINDOW”, “高度”, 到文本 (_启动窗口.高度))

写配置项 (配置文件名, “WINDOW”, “宽度”, 到文本 (_启动窗口.宽度))

.子程序 处理, 整数型

.参数 hwnd, 整数型

.参数 Msg, 整数型

.参数 wp, 整数型

.参数 lp, 整数型

.判断开始 (Msg = #WM_MOVING) ' 正在移动

 限制移动或大小 (lp, 0)

 .如果真 (停靠 ≠ 0) ' 移动禁止依靠

  停靠 = 0

  正在收放 = 0

 .如果真结束

.判断 (Msg = #WM_GETMINMAXINFO) ' 正在获得大小消息

 .如果真 (正在收放 = 0)

  限制移动或大小 (lp, 1)

 .如果真结束

.判断 (Msg = #WM_SIZING) ' 正在改变大小

 .如果真 (停靠 ≠ 0) ' 大小禁止依靠

  停靠 = 0

  正在收放 = 0

 .如果真结束

.判断 (Msg = #WM_SIZE) ' 大小已改变

 判断停靠 ()

.判断 (Msg = #WM_MOVE) ' 位置已移动

 .如果真 (正在收放 = 0) ' 无收放动作

  判断停靠 ()

 .如果真结束

.判断 (Msg = #WM_EXITSIZEMOVE)

 判断停靠 ()

.判断 (Msg = #WM_NCLBUTTONDOWN) ' 标题栏鼠标按下

 .如果真 (停靠 ≠ 0)

  .如果真 ((已收起 或 正在收放 ≠ 0) 且 wp ≠ 2) ' 禁止大小

   Msg = 0

  .如果真结束

 .如果真结束

.判断 (Msg = #WM_SYSCOMMAND) ' 系统菜单

 .如果真 ((已收起 或 正在收放 ≠ 0) 且 wp = 61440) ' 收起了禁止调整大小

  Msg = 0

 .如果真结束

.默认

.判断结束

返回 (呼叫窗口函数地址_ (原窗口, hwnd, Msg, wp, lp))

.子程序 判断停靠

.判断开始 (顶边 < 2)

 _启动窗口.移动 (, 0, , ) ' 这里可写吸附

 停靠 = 2 ' 上

 .如果真 (时钟 = 0)

  时钟 = 设置时钟_ (取窗口句柄 (), 1036, 100, 到整数 (&判断收放))

 .如果真结束

.判断 (左边 < 2)

 停靠 = 1 ' 左

 _启动窗口.移动 (0, , , )

 .如果真 (时钟 = 0)

  时钟 = 设置时钟_ (取窗口句柄 (), 1036, 100, 到整数 (&判断收放))

 .如果真结束

.判断 (左边 > 取屏幕宽度 () - 宽度 - 2)

 停靠 = 3 ' 右

 _启动窗口.移动 (取屏幕宽度 () - 宽度, , , )

 .如果真 (时钟 = 0)

  时钟 = 设置时钟_ (取窗口句柄 (), 1036, 100, 到整数 (&判断收放))

 .如果真结束

.默认

 停靠 = 0

 .如果真 (时钟 ≠ 0)

  销毁时钟_ (取窗口句柄 (), 1036)

  时钟 = 0

 .如果真结束

.判断结束

.如果真 (已收起)

 判断收起 ()

.如果真结束

.子程序 判断收起

.判断开始 (顶边 = 5 - 高度 或 左边 = 5 - 宽度 或 左边 = 取屏幕宽度 () - 5)

 已收起 = 真

.默认

 已收起 = 假

.判断结束

.子程序 限制移动或大小, , , 0移动,非0大小

.参数 lp, 整数型, 参考

.参数 移动或大小, 整数型

.局部变量 a, MINMAXINFO

' 分开子程序是不想鼠标移动等等其它信息也分一个变量空间,个人猜想

.判断开始 (移动或大小 = 0)

 复制内存1_ (a, lp, 40) ' 40为MINMAXINFO结构长度

 .如果真 (a.ptReserved.横向位置 < 2) ' 靠边像磁铁一样,为0就不吸啦

  a.ptReserved.横向位置 = 0

  a.ptMaxSize.横向位置 = 0 + 宽度

 .如果真结束

 .如果真 (a.ptReserved.纵向位置 < 2)

  a.ptReserved.纵向位置 = 0

  a.ptMaxSize.纵向位置 = 0 + 高度

 .如果真结束

 .如果真 (a.ptMaxSize.横向位置 > 取屏幕宽度 () - 2)

  a.ptReserved.横向位置 = 取屏幕宽度 () - 宽度

  a.ptMaxSize.横向位置 = 取屏幕宽度 ()

 .如果真结束

 .如果真 (a.ptMaxSize.纵向位置 > 取屏幕高度 ()) ' 这里是限制窗口下边不越出屏幕之外的代码.

  a.ptReserved.纵向位置 = 取屏幕高度 () - 高度

  a.ptMaxSize.纵向位置 = 取屏幕高度 ()

 .如果真结束

 复制内存_ (lp, a, 40) ' 40为MINMAXINFO结构长度

.默认

 复制内存1_ (a, lp, 40) ' 40为MINMAXINFO结构长度

 a.ptMinTrackSize.横向位置 = 188 ' 最小X

 a.ptMinTrackSize.纵向位置 = 250 ' 最小Y

 ' ' a.ptMaxTrackSize.横向位置 = 取屏幕宽度 () ' 最大X

 ' ' a.ptMaxTrackSize.纵向位置 = 取屏幕高度 () ' 最大Y

 复制内存_ (lp, a, 40) ' 40为MINMAXINFO结构长度

.判断结束

' ZeroMemory (a, 40)

.子程序 判断收放

.局部变量 x, 整数型

.局部变量 y, 整数型

x = 取鼠标水平位置 ()

y = 取鼠标垂直位置 ()

.判断开始 (x < 左边 或 x > 左边 + 宽度 或 y < 顶边 或 y > 顶边 + 高度)

 .如果真 (正在收放 = 2) ' 正在展开时收起

  正在收放 = 0

  延时 (10)

  .如果真 (停靠 ≠ 0)

   窗口收起 ()

  .如果真结束

 .如果真结束

 .判断开始 (已收起)

  计数 = 0

 .默认

  .判断开始 (停靠 = 0)

   计数 = 0

  .默认

   计数 = 计数 + 1

  .判断结束

  .如果真 (计数 = 10) ' 1秒收起

   计数 = 0

   .如果真 (正在收放 ≠ 1)

    窗口收起 ()

   .如果真结束

  .如果真结束

 .判断结束

.默认

 .判断开始 (已收起)

  计数 = 计数 + 1

  .如果真 (计数 = 10) ' 1秒展开

   计数 = 0

   .如果真 (正在收放 ≠ 2 且 停靠 ≠ 0)

    窗口展开 ()

   .如果真结束

  .如果真结束

 .默认

  计数 = 0

 .判断结束

 .如果真 (正在收放 = 1) ' 正在收起时展开

  正在收放 = 0

  延时 (10)

  .如果真 (正在收放 ≠ 2 且 停靠 ≠ 0)

   窗口展开 ()

  .如果真结束

 .如果真结束

.判断结束

.子程序 窗口收起

.局部变量 x, 整数型

.局部变量 y, 整数型

正在收放 = 1

.判断开始 (停靠 = 1) ' 左

 x = _启动窗口.左边

 .判断循环首 (x > 7 - _启动窗口.宽度)

  处理事件 ()

  .如果真 (正在收放 ≠ 1 或 停靠 = 0)

   返回 ()

  .如果真结束

  延时 (10)

  x = x - 步进长度 ' 5

  _启动窗口.移动 (x, , , )

 .判断循环尾 ()

 _启动窗口.移动 (最小尺寸 - _启动窗口.宽度, , , ) ' 5

.判断 (停靠 = 3) ' 右

 x = 左边

 y = 取屏幕宽度 ()

 .判断循环首 (x < y - 7)

  处理事件 ()

  .如果真 (正在收放 ≠ 1 或 停靠 = 0)

   返回 ()

  .如果真结束

  延时 (10)

  x = x + 步进长度 ' 5

  _启动窗口.移动 (x, , , )

 .判断循环尾 ()

 _启动窗口.移动 (y - 最小尺寸, , , )

.判断 (停靠 = 2) ' 上

 x = 顶边

 .判断循环首 (x > 7 - 高度)

  处理事件 ()

  .如果真 (正在收放 ≠ 1 或 停靠 = 0)

   返回 ()

  .如果真结束

  延时 (10)

  x = x - 步进长度 ' 5

  _启动窗口.移动 (, x, , )

 .判断循环尾 ()

 _启动窗口.移动 (, 最小尺寸 - _启动窗口.高度, , )

.默认

.判断结束

' 销毁时钟_ (取窗口句柄 (), 1036)

' 时钟=0

已收起 = 真

正在收放 = 0

总在最前 = 真

调整层次 (#顶层)

调整层次 (#最高层)

.子程序 窗口展开

.局部变量 x, 整数型

.局部变量 y, 整数型

正在收放 = 2

已收起 = 假

_启动窗口.总在最前 = 真

_启动窗口.总在最前 = 假

.判断开始 (停靠 = 2) ' 上

 x = _启动窗口.顶边

 .判断循环首 (x < -7)

  处理事件 ()

  .如果真 (正在收放 ≠ 2 或 停靠 = 0)

   返回 ()

  .如果真结束

  延时 (10)

  x = x + 步进长度 ' 5

  _启动窗口.移动 (, x, , )

 .判断循环尾 ()

 _启动窗口.移动 (, 0, , )

.判断 (停靠 = 1) ' 左

 x = 左边

 .判断循环首 (x < -7)

  处理事件 ()

  .如果真 (正在收放 ≠ 2 或 停靠 = 0)

   返回 ()

  .如果真结束

  延时 (10)

  x = x + 步进长度 ' 5

  _启动窗口.移动 (x, , , )

 .判断循环尾 ()

 _启动窗口.移动 (0, , , )

.判断 (停靠 = 3) ' 右

 x = 左边

 y = 取屏幕宽度 ()

 .判断循环首 (x > y - _启动窗口.宽度 + 7)

  处理事件 ()

  .如果真 (正在收放 ≠ 2 或 停靠 = 0)

   返回 ()

  .如果真结束

  延时 (10)

  x = x - 步进长度 ' 5

  _启动窗口.移动 (x, , , )

 .判断循环尾 ()

 _启动窗口.移动 (y - _启动窗口.宽度, , , )

.默认

.判断结束

正在收放 = 0

_启动窗口.激活 ()

总在最前 = 真

调整层次 (#顶层)

调整层次 (#最高层)

.子程序 __启动窗口_将被销毁

设置窗口信息_ (取窗口句柄 (), #GWL_WNDPROC, 原窗口)

.如果真 (时钟 ≠ 0)

 销毁时钟_ (取窗口句柄 (), 1036)

.如果真结束

.如果真 (正在收放 ≠ 0)

 正在收放 = 0

.如果真结束

将被销毁保存位置 ()

复制DLL:

.版本 2

.DLL命令 设置窗口信息_, 整数型, "user32", "SetWindowLongA", , 在窗口结构中为指定的窗口设置信息 指定数据的前一个值

 .参数 窗口句柄, 整数型, , hwnd,欲为其取得信息的窗口的句柄

 .参数 窗口信息值, 整数型, , nIndex,请参考GetWindowLong函数的nIndex参数的说明

 .参数 窗口信息新值, 整数型, , dwNewLong,由nIndex指定的窗口信息的新值

.DLL命令 呼叫窗口函数地址_, 整数型, "user32.dll", "CallWindowProcA", , CallWindowProcA将消息传答窗口函数 

 .参数 前一窗口函数地址, 整数型, , lpPrevWndFunc

 .参数 窗口句柄, 整数型, , hwnd

 .参数 消息值, 整数型, , msg

 .参数 附加参数1, 整数型, , wParam

 .参数 附加参数2, 整数型, , lParam

.DLL命令 复制内存_, , "kernel32.dll", "RtlMoveMemory", , CopyMemory

 .参数 pDest, 整数型

 .参数 pSrc, MINMAXINFO

 .参数 ByteLen, 字节型

.DLL命令 复制内存1_, , "kernel32.dll", "RtlMoveMemory", , CopyMemory1 

 .参数 pDest, MINMAXINFO

 .参数 pSrc, 整数型

 .参数 ByteLen, 字节型

.DLL命令 设置时钟_, 整数型, "user32.dll", "SetTimer", , SetTimer

 .参数 窗口句柄, 整数型, , hwnd

 .参数 事件标识符, 整数型, , nIDEvent

 .参数 时钟周期, 整数型, , uElapse

 .参数 回调函数地址, 整数型, , lpTimerFunc

.DLL命令 销毁时钟_, 整数型, "user32.dll", "KillTimer", , KillTimer

 .参数 窗口句柄, 整数型, , hwnd

 .参数 事件标识符, 整数型, , nIDEvent

.DLL命令 内存清零_, , "kernel32.dll", "RtlZeroMemory", , ZeroMemory将一块内存置零

 .参数 目的内存, MINMAXINFO, 传址, Destination

 .参数 长度, 整数型, , Length

复制自定义数据:

.版本 2

.数据类型 坐标, , 坐标;POINTAPI

 .成员 横向位置, 整数型, , , X坐标

 .成员 纵向位置, 整数型, , , Y坐标

.数据类型 MINMAXINFO, , MINMAXINFO

 .成员 ptReserved, 坐标

 .成员 ptMaxSize, 坐标

 .成员 ptMaxPosition, 坐标

 .成员 ptMinTrackSize, 坐标

 .成员 ptMaxTrackSize, 坐标

复制常量数据:

.版本 2

.常量 GWL_WNDPROC, "-4"

.常量 WM_GETMINMAXINFO, "36", , 此消息发送给窗口当它将要改变大小或位置;

.常量 WM_MOUSEMOVE, "512"

.常量 WM_NCMOUSEMOVE, "160"

.常量 WM_EXITSIZEMOVE, "562"

.常量 WM_MOVING, "534"

.常量 WM_MOVE, "3"

.常量 WM_NCHITTEST, "132"

.常量 WM_NCLBUTTONDOWN, "161"

.常量 WM_NCLBUTTONUP, "162"

.常量 WM_SIZE, "5"

.常量 WM_SIZING, "532"

.常量 WM_SYSCOMMAND, "274"

.常量 WM_KEYUP, "257"

.常量 WM_KEYDOWN, "256"

狂击F5调试程序。

以上就是关于易语言隐藏窗口的全部内容,感谢大家对我们的支持。

(0)

相关推荐

  • 易语言编写窗口抖动程序教学

    易语言是一门以中文作为程序代码编程语言.以"易"著称.创始人为吴涛.早期版本的名字为E语言.易语言最早的版本的发布可追溯至2000年9月11日.创造易语言的初衷是进行用中文来编写程序的实践.从2000年至今,易语言已经发展到一定的规模,功能上.用户数量上都十分可观.那么易语言如何编写窗口抖动呢?下面小编为大家讲解! 1.新建一个windows窗口程序! 2.将一个按钮放在启动窗口内.改按钮标题为抖动. 3.双击按钮1,开始编写. 4.写入代码,如下 _启动窗口.左边 = _启动窗口.左

  • 易语言更改窗口标题的方法

    本经验小谈下怎么静态更改窗口标题,以及怎么在程序运行中进发窗口标题 1.在新建的空白程序中,点击窗口的空白部分选择窗体 2.在左侧列表下方选中"属性"面板 3.在窗体属性面板中找到"标题"属性,在该属性对应的输入框中输入想要更改的标题,这就是易语言静态更改窗口标题的方法 1.易语言动态更改窗口标题 在新建的空白程序中,双击窗体的空白区域,进入代码编辑面板 2.在"__启动窗口_创建完毕"子程序下,输入:_启动窗口.标题 = "想要更改的

  • 易语言如何多窗口操作?易语言增加窗口

    易语言如何制作一款多窗口的软件呢,让我们一起来看看. 1.打开易语言. 2.如图为编辑窗口. 3.把工作区切换为"程序" 4.单机"窗口" 5.右键. 6.选择"插入新窗口" 7.便创建好了"窗口一". 8.我们双击这两个任意一个便可以切换. 9.作者更改了图像来区别. 10.大家学会了吗? 总结:多窗口操作不仅能让几个界面项目查看更加简洁,还提升了工作效率,感谢大家的阅读和对我们的支持.

  • 实例操作易语言载入窗口

    使用易语言载入窗口 1.打开您的易语言,选择"Windows 窗口程序" 2.设计好您的程序后 3.点击这里,插入-----窗口 4.这时候就会出现一个新的窗口    默认命名为"窗口一" 5.同样设计好它 6.现在我们要做的就是通过点击这个按钮来来载入"窗口一" 7.双击它.就会进入如图所示的代码编辑区 这里  按钮一被单击  的意思就是下面这行代码的执行条件就是 按钮一被单击 8.很简单的一行代码就能实现窗口的载入. 如图所示 载入(窗口1,

  • 易语言新建窗口的步骤教学

    易语言是一款汉化过来的编译软件,像C++,JAVA等等编译软件,易语言比较好学,但是编程软件的时候一般都会新建一个窗口,所以我们来萱萱如何新建窗口. 第一,先找到易语言并且打开,进入, 进入后我们看到一个易语言软件窗口. 找到左上角的程序,点击它. 点击新建,就会弹出一个选择新建窗口类型. 新建窗口类型选择第一个,点击它. 点击后我们就看到我们新建出来的一个窗口. 这个新建的窗口可以编译了,比如设置按钮设置背景等等. 以上就是易语言新建窗口的步骤,很简单,跟着学习一下吧,感谢大家对我们的支持.

  • 易语言窗口跳转程序的编写技巧

    看到别人写的小软件能够实现菜单跳转到下一个窗口,是不是觉得很有用,今天就来教大家怎么写一个简单的跳转程序,这里我就以一个连续答题的方式逐步实现跳转,答题完成后,系统提示回答完毕,并自动关闭程序. 1.当做好写软件的准备工作后,就可以正式开始了. 2.在新建的windows窗口上添加一个编辑框,两个按钮,如图,点了右边的选项后,在Windows窗口上按下左键拖动就形成了. 3.下面我们需要美化一下程序窗口,在美化之前,需要知道怎么设置,图片上已经说的很清楚了,按照操作顺序来进行就OK. 4.现在开

  • 易语言窗口平行跟随的操作方法

    易语言其他窗口跟随启动窗口平行移动! 1.新建一个程序并设置好启动窗口的高度跟宽度.插入窗口(窗口1),将窗口1的高度跟启动窗口的高度设置为同等高度. 我这里设置的高度为400 2.左键双击启动窗口,进入到启动窗口程序集. 在启动窗口创建完毕的子程序下写入代码: 目的是为为了让窗口1跟启动窗口同时打开. .版本 2 .子程序 __启动窗口_创建完毕 载入 (窗口1, , 假) 3.左键双击窗口,进入到窗口1程序集. 在窗口1创建完毕的子程序下写入代码: .版本 2 窗口1.左边 = _启动窗口.

  • 易语言隐藏窗口图文教程

    本经验可以帮你的软件添加像气QQ一样的伸缩窗口 新建一个Windows窗口程序 双击启动窗口,输入代码: .版本 2 .支持库 spec .程序集 窗口程序集1 .程序集变量 原窗口, 整数型 .程序集变量 停靠, 整数型, , , 1左,2上,3右,0为不 .程序集变量 正在收放, 整数型, , , 1收,2放 .程序集变量 计数, 整数型 .程序集变量 已收起, 逻辑型 .程序集变量 时钟, 整数型 .程序集变量 步进长度, 整数型, , , 新加的 .程序集变量 最小尺寸, 整数型, ,

  • Go语言快速入门图文教程

    推荐阅读: go语言最新版激活教程可以点下这个链接查看. goland永久安装教程,点击此处查看. Go 这几年很火,小哈也蹭业余时间悄咪咪学习一下(我大 Java 依旧无敌

  • 实例讲述易语言拦截窗口消息

    易语言等可视化编程已经将视窗消息封装为对象的属性.方法和事件.当我们在窗口中按下鼠标左键,欲出现信息"你点击了窗体",在易语言中是这样编写的: 子程序:__启动窗口_鼠标左键被按下 返回值类型:逻辑型 参数:横向位置 数据类型:整数型 参数:纵向位置 数据类型:整数型 参数:功能键状态 数据类型:整数型 信息框 ("你点击了窗体", 0, ) 但是如果不用"__启动窗口_鼠标左键被按下"事件能否达到这样的结果?由于对象的事件也只不过是视窗消息的封

  • VScode上配置 c语言环境的图文教程

    成成最近用到C语言了,之前比较喜欢用在vscode上面用python调试,今天我参考了一些文章,也尝试了下在vscode上配置c语言的调试,其中包含一些相关的基础知识. 1.在vscode里面下载c/c++官方插件: 2.安装c/c++编译器: 在windows上借助MinGW工具安装,下载地址:[https://sourceforge.net/projects/mingw/ ] 安装在d:\MinGW 下就好(自己新建一个文件夹),然后打开后这个样子: 在里面找到mingw32-gcc.bin

  • 易语言API取文本长度图文讲解

    windows API 应用之"lstrlen"的应用 用易语言取出文本长度的实例教程 1.新建一个易语言窗口程序 添加一个编辑框 和 按钮组件 2.添加需要取出长度的文本 如图中所示 编辑框中添加 "百度一下你就知道"文字 3.双击DLL命令 进入DLL编辑代码 4.新建DLL命令 写入以下代码 .版本 2 .DLL命令 lstrlen, 整数型, , "lstrlenA" .参数 lpString, 文本型 5.进入程序集 写出以下代码 我们

  • 易语言让窗口透明化的操作方法

    很多时候,我们看到有的软件的窗口可以透明,感觉很神奇.是不是也想摩拳擦掌尝试一下呢?好了,今天MovieClip就给大家说一下,易语言怎么让窗口透明呢?言归正传吧! 易语言怎么让窗口透明 首先,打开易语言,新建"Windows窗口程序",点击"确定"按钮进入"Windows窗口"设计界面.如图: 在窗口上,绘制一个编辑框.一个按钮组件.调整相关组件的尺寸和位置.如图: 修改相关组件的属性值并规范命名各组件的名称,以方便后续的代码编写.如图: 进入

随机推荐