用vbs检测Internet Explorer 中是否启用了 ActiveX

问:

您好,脚本专家!如何知道 Internet Explorer 中是否启用了 ActiveX?

-- JV

答:

您好,JV。您一定要问这个问题,是吗?实际上,这并不是一个特别难回答的问题,只是有点复杂。不过,那与配置 Internet Explorer 的方式紧密相关,而与通过编写一个脚本来检索此信息关系不大。

首先,Internet Explorer 没有管理对象模型;相反,我们能够通过编程的方式检索 Internet Explorer 设置和属性值的唯一方法就是通过编写一个脚本来从注册表中获取此信息。这相当容易;我们经常在本专栏中使用注册表读取的脚本。最为棘手的部分就是搞清楚需要读取哪个注册表值,并知道如何解释返回的数据。





注意:另一个棘手的部分在于知道您对哪个 ActiveX 设置感兴趣;不论好坏,Internet Explorer 有与 ActiveX 控件相关的多个设置。在今天的专栏中,我们假定您要读取此设置的值:运行 ActiveX 控件和插件

让我们先从搞清楚需要修改哪些注册表值开始。实际上,Internet Explorer 安全设置没有全局设置;相反,这些设置由 Internet Explorer 区域进行管理。有四个这样的安全区域;区域名及其值如下表所示:


















区域名

区域值

Intranet 站点

1

受信任的站点

2

Internet 站点

3

受限制的站点

4

可在注册表的 HKEY_CURRENT_USER\ Software\Microsoft\Windows\CurrentVersion\Internet Settings\Zones\ 部分中找到 Internet Explorer 安全区域的设置;要访问某个特定区域,您需要访问与该区域对应的子项。要确定相应的子项,只需将区域值追加到前面的注册表路径即可。例如,要获取 Internet 站点区域(值 3)的设置,您需要访问以下注册表子项:

HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings\Zones\3

您能看到 3 被追加到了末尾处。要访问 Intranet 站点区域(值 1)的设置?没问题:

HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings\Zones\1

找到正确的注册表子项后,您需要知道要读取哪个注册表值。遗憾的是(至少对于脚本编写者来说),这些注册表值的名称有点含糊;例如,我们感兴趣的名称为 1200。(为什么是这样呢?我们不知道。)如果您对使用脚本来读取/管理 Internet Explorer 设置感兴趣,那么,您可能希望阅读一下 Managing Internet Explorer Enhanced Security Configuration whitepaper(英文)。仅一部分文档会涉及脚本编写,但是,该部分的确将这些含糊的注册表值映射到了用户界面中的相应属性。当然,许多这样的设置都可在 Tweakomatic 中找到。(Tweakomatic 与白皮书不同,它会真正地为您编写脚本。)

那么,我们已准备最终编写一个脚本并真的在此执行一些操作吗?几乎是这样。您需要知道的另一件事就是配置信息作为双字节(数字)值被存储在注册表中。如果您知道 ActiveX 控件被配置为 3 而不是 65536,这会有所帮助吗?可能没有。不过,下表可能有所帮助:


















注册表值

用户界面值

0

Enabled

1

Prompt

3

Disabled

65536

Administrator Approved

不,最后一个值并非印刷错误,它的确 65536。自己去想吧。

那好,现在我们就准备编写一个脚本。下面的这个示例脚本可检索 Intranet 站点区域(区域值 1)的设置信息:

HKEY_CURRENT_USER = &H80000001

strComputer = "."
Set objReg = GetObject("winmgmts:\\" & strComputer & "\root\default:StdRegProv")

strKeyPath = "Software\Microsoft\Windows\CurrentVersion\Internet Settings\Zones\1"
ValueName = "1200"

objReg.GetDWORDValue HKEY_CURRENT_USER, strKeyPath, ValueName, dwValue

Wscript.Echo "Run ActiveX Controls and Plug-ins"

If IsNull(dwValue) Then
Wscript.Echo "Intranet sites: The value is either Null or could not be found in the registry."
ElseIf dwValue = 0 Then
Wscript.Echo "Intranet sites: Enabled"
ElseIf dwValue = 1 Then
Wscript.Echo "Intranet sites: Prompt"
ElseIf dwValue = 3 Then
Wscript.Echo "Intranet sites: Disabled"
ElseIf dwValue = 65536 Then
Wscript.Echo "Intranet sites: Administrator Approved"
End If


我们首先定义一个名为 HKEY_CURRENT_USER 的常量并将其值设置为 &H80000001;这将告诉脚本我们要使用哪个注册表配置单元。然后我们连接到 WMI 服务;请注意,StdRegProv(标准注册表提供程序)类位于 root\default 命名空间中。(许多脚本编写者都认为该类与大多数 WMI 类一样,都位于 root\cimv2 中。事实并非如此。)

接下来我们将为一对变量赋值:

strKeyPath = "Software\Microsoft\Windows\CurrentVersion\Internet Settings\Zones\1"
ValueName = "1200"

正如您所看到的,变量 strKeyPath 包含 HKEY_CURRENT_USER 中的注册表路径(请勿在该路径中包含 HKEY_CURRENT_USER,否则,脚本将失败)。同时,将变量 ValueName 设置为 1200,该值恰好为我们要读取的注册表值。

然后我们调用 GetDWORDValue 方法,这样我们可读取注册表中的双字节值:

objReg.GetDWORDValue HKEY_CURRENT_USER, strKeyPath, ValueName, dwValue

请注意,我们需要向 GetDWORDValue 传递几个参数:














HKEY_CURRENT_USER,告诉脚本要使用哪个注册表配置单元的常量。

strKeyPath,包含注册表路径的变量。

ValueName,表示我们要读取的注册表值的变量。

dwValue,将结束存储从注册表中读取的值的“输出参数”。如果您正在想,“请稍等,我们没有为 dwValue 赋值,”您说对了。我们就是这样设计的:我们为输出参数赋值。相反,GetDWORDValue 将读取恰好存储在所讨论的注册表值 (1200) 中的任何值,然后该方法会将该值赋给 dwValue。

确实很不错,不是吗?

此时,我们可只回显从注册表中检索的值。不过,正如我们所指出的那样,该检索值将为诸如 1、3 或 65536 这样的值。因此,我们建立一个简单小巧的 If Then ElseIf 块以检查返回值,并回显一个更有意义的消息:

If IsNull(dwValue) Then
Wscript.Echo "Intranet sites: The value is either Null or could not be found in the registry."
ElseIf dwValue = 0 Then
Wscript.Echo "Intranet sites: Enabled"
ElseIf dwValue = 1 Then
Wscript.Echo "Intranet sites: Prompt"
ElseIf dwValue = 3 Then
Wscript.Echo "Intranet sites: Disabled"
ElseIf dwValue = 65536 Then
Wscript.Echo "Intranet sites: Administrator Approved"
End If

您说对了:一旦您知道值存储在注册表中的什么位置以及如何将值存储在注册表中,这就相当容易了。

仅仅为了省去键入(和/或复制与粘贴)之苦,下面的脚本可返回所有四个安全区域的信息:

HKEY_CURRENT_USER = &H80000001

strComputer = "."
Set objReg = GetObject("winmgmts:\\" & strComputer & "\root\default:StdRegProv")

strKeyPath = "Software\Microsoft\Windows\CurrentVersion\Internet Settings\Zones\1"
ValueName = "1200"
objReg.GetDWORDValue HKEY_CURRENT_USER, strKeyPath, ValueName, dwValue

Wscript.Echo "Run ActiveX Controls and Plugins"

If IsNull(dwValue) Then
Wscript.Echo "Intranet sites: The value is either Null or could not be found in the registry."
ElseIf dwValue = 0 Then
Wscript.Echo "Intranet sites: Enabled"
ElseIf dwValue = 1 Then
Wscript.Echo "Intranet sites: Prompt"
ElseIf dwValue = 3 Then
Wscript.Echo "Intranet sites: Disabled"
ElseIf dwValue = 65536 Then
Wscript.Echo "Intranet sites: Administrator Approved"
End If

strKeyPath = "Software\Microsoft\Windows\CurrentVersion\Internet Settings\Zones\2"
ValueName = "1200"

objReg.GetDWORDValue HKEY_CURRENT_USER, strKeyPath, ValueName, dwValue

If IsNull(dwValue) Then
Wscript.Echo "Trusted sites: The value is either Null or could not be found in the registry."
ElseIf dwValue = 0 Then
Wscript.Echo "Trusted sites: Enabled"
ElseIf dwValue = 1 Then
Wscript.Echo "Trusted sites: Prompt"
ElseIf dwValue = 3 Then
Wscript.Echo "Trusted sites: Disabled"
ElseIf dwValue = 65536 Then
Wscript.Echo "Trusted sites: Administrator Approved"
End If

strKeyPath = "Software\Microsoft\Windows\CurrentVersion\Internet Settings\Zones\3"
ValueName = "1200"

objReg.GetDWORDValue HKEY_CURRENT_USER, strKeyPath, ValueName, dwValue

If IsNull(dwValue) Then
Wscript.Echo "Internet sites: The value is either Null or could not be found in the registry."
ElseIf dwValue = 0 Then
Wscript.Echo "Internet sites: Enabled"
ElseIf dwValue = 1 Then
Wscript.Echo "Internet sites: Prompt"
ElseIf dwValue = 3 Then
Wscript.Echo "Internet sites: Disabled"
ElseIf dwValue = 65536 Then
Wscript.Echo "Internet sites: Administrator Approved"
End If

strKeyPath = "Software\Microsoft\Windows\CurrentVersion\Internet Settings\Zones\4"
ValueName = "1200"

objReg.GetDWORDValue HKEY_CURRENT_USER, strKeyPath, ValueName, dwValue

If IsNull(dwValue) Then
Wscript.Echo "Restricted sites: The value is either Null or could not be found in the registry."
ElseIf dwValue = 0 Then
Wscript.Echo "Restricted sites: Enabled"
ElseIf dwValue = 1 Then
Wscript.Echo "Restricted sites: Prompt"
ElseIf dwValue = 3 Then
Wscript.Echo "Restricted sites: Disabled"
ElseIf dwValue = 65536 Then
Wscript.Echo "Restricted sites: Administrator Approved"
End If


运行脚本,将返回类似下面内容的输出:

Run ActiveX Controls and Plugins
Intranet sites: Enabled
Trusted sites: Enabled
Internet sites: Enabled
Restricted sites: Disabled

在此我们还能再做些什么吗?或许可以;毕竟我们还可配置此注册表值。但那是改天要讨论的内容了。

时间: 2007-03-26

用vbs返回 Internet Explorer 的下载控件和 Applet 的列表

问: 嗨,Scripting Guy!要找出已为 Internet Explorer 下载了哪些程序,有没有简便的方法(这些项目在文件夹 C:\Windows\Downloaded Program Files 中)?我可以使用一个脚本获得可执行文件名和依存文件,但是我想获得它们显示在文件夹中的文件名. -- AC 答: 您好,AC.当您下载了 ActiveX 控件或 Java 小程序时,这些项目通常会放置在"Downloaded Program"文件夹中.您可以在 Windows 资源

用vbs更改 Internet Explorer 的标题栏

问: 您好,脚本专家!最近我注册了新的 Internet 服务,现在每次我启动 Internet Explorer 时窗口标题显示 Internet Explorer 由 Fabrikam.com 提供.如何更改 Internet Explorer 的标题栏? -- AD 答: 您好,AD.您知道,您的问题让脚本专家在道德和伦理方面进退两难.在我们收到您的电子邮件的同时,我们收到了另一封电子邮件,其内容如下: "您好,脚本专家!我知道许多公司配置了 Internet Explorer,从而其用户

用vbs实现重新启动 Internet Explorer

问: 您好,脚本专家!如果未运行其他实例,如何重新启动 Internet Explorer? -- MT 答: 您好,MT.多谢您的问题.您知道,如今每个人都在挑剔可怜的 Internet Explorer 的毛病(尽管大多数 Windows 用户仍在使用 Internet Explorer).但现在有人提出了一个问题,他想确保 Internet Explorer 始终正常运行.看见了吧,Internet Explorer:还有人喜欢你! 尽管我们本来要为 Internet Explorer 而

ibm官方资料把应用程序从 Internet Explorer 迁移到 Mozilla第1/2页

Netscape 最初开发 Mozilla 浏览器的时候,明智地决定支持 W3C 标准.因此,Mozilla 和 Netscape Navigator 4.x 以及 Microsoft Internet Explorer 遗留代码不完全向后兼容,比如后面将提到 Mozilla 不支持 <layer>.Internet Explorer 4 这些在 W3C 标准的概念出现之前建立的浏览器继承了很多古怪之处.本文中将讨论 Mozilla 的特殊模式,它为 Internet Explorer 和其他

Internet Explorer 11 浏览器介绍:别叫我IE

在上个星期,微软随Windows 8.1正式推出了Internet Explorer 11的第一次预览版.这样,关于这款备受争议的web浏览器泄露版本的各种传闻也该休息了.我们现在已经知道一些关于Internet Explorer 11的重要的细节,包括支持WebGL ,prefetch(译者注:预读取,比如上传文件的预览啥的,不知道翻译的对不对),prerender(预呈现), flexbox,mutation observers和其他web标准,也许在IE11中更有趣的是,它是不是IE. 长

开发 Internet Explorer 右键功能表(ContextMenu)

参考 MSDN Library[Adding Entries to the Standard Context Menu]开发 ContextMenu 1. IE 额外的 ContextMenu 是透过註册机码 HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\MenuExt 来建立 2. 所以只要在该位置下新增一个 Key 值,例如:新增[Make 0rz]则 IE 中按下右键就会出现相同名称的功能 3. 如果我们想要在该功能上可以使用

用vbs 实现从剪贴板中抓取一个 URL 然后在浏览器中打开该 Web 站点

问: 嗨,Scripting Guy!我如何从剪贴板中抓取一个 URL 然后在浏览器中打开该 Web 站点? -- CL 答: 您好,CL.这是很有趣的问题,或者我们应当说,这是两个很有趣的问题.因为您实际上问了两个问题.第一个问题很简单:我可以使用脚本打开特定的 Web 站点吗?您大概已经知道答案了,我可以大声地回答您,可以!下面是一个示例脚本,它将"脚本中心"的 URL 存储在一个名为 strURL 的变量中.然后,此脚本会创建 WSH Shell 对象的一个实例,并使用 Run 

小心!Internet Explorer新漏洞

安全机构Secunia有新的消息有关微软的Internet Explorer,Secunia指出Internet Explorer新的问题已经呈现出来,而且所有的这些都是非常的严重的,并且所有的这些潜在的问题都将会对Internet Explorer的使用者造成重大的破坏. 第一个问题涉及到IE未能对从Internet上传送到本地的一些项目进行效验.IE未能对图像或者其他媒体所隐含的HTML编码进行效验,这样会造成站点能够将HTML编码植入到使用者的系统中,随后可以让这些HTML编码在本地被执行

IE autocomplete internet explorer's autocomplete

IE autocomplete internet explorer's autocomplete Frequently people are confused by the various dropdown quick-complete boxes in IE.  Most people lump them all under the term "AutoComplete."  There are actually several features in play, and today