ASP知识讲座四

ASP内置组件

前三讲中，我们主要介绍了ASP提供的四大内置对象：
l Response对象：向浏览器发送信息。
l Request对象：访问从浏览器发送到服务器的信息（如获取表单数据）。
l Session对象：存储、读取特定用户对话信息。
l Application对象：存储、读取所有用户共享的应用程序信息。
此外还有Server对象和ObjectContext对象我们将在以后的实例中学习（提示：其实不经意之间你已经可以利用所学知识编写网上聊天室了）。本讲的内容是使用ASP的ActiveX Server Components（组件）。

一、 Browser Capabilities Component（浏览器能力组件）： 
我们知道，不同的浏览器也许支持不同的功能，如有些浏览器支持框架，有些不支持。利用这个组件，可以检查浏览器的能力，使你的网页争对不同的浏览器显示不同的页面（如对不支持Frame的浏览器显示不含Frame的网页）。该组件的使用很简单，需注意的是，要正确使用该组件，必须保证Browscap.ini文件是最新的（其实每一个浏览器及其特性都列在这个文件中，自己打开看看就明白了）,否则结果可能相去甚远，如Win98第二版所带的IE5.0，在下例中显示为Netscape。这个文件一般位于Web服务器的"\Winnt\System32\InetSrv"下，最新的版本可去http://www.asptracker.com/或http://www.cyscape.com/browscap下载。
例：wuf22.asp
<html>
<BODY>
'注意：组件的使用与对象类似，但是组件在使用前必须先创建，而使用内置对象前不必创建。
<%Set BrowsCap=Server.CreateObject("MSWC.BrowserType")%>
请稍候......
<P>
<TABLE BORDER=1 CELLPADDING=10>
<TR><TD>浏览器类型</TD><TD><%=BrowsCap.Browser%></TD></TR>
<TR><TD>浏览器版本</TD><TD><%=BrowsCap.version%></TD></TR>
<TR><TD>是否支持表格</TD><TD><%=BrowsCap.tables%></TD></TR>
<TR><TD>是否支持ActiveX控件</TD><TD><%=BrowsCap.activexcontrols%></TD></TR>
<TR><TD>是否支持JavaApplets</TD><TD><%=BrowsCap.javaapplets%></TD></TR>
<TR><TD>是否支持JavaScript</TD><TD><%=BrowsCap.javascript%></TD></TR>
<TR><TD>是否支持Cookies</TD><TD><%=BrowsCap.Cookies%></TD></TR>
<TR><TD>是否支持Frames</TD><TD><%=BrowsCap.Frames%></TD></TR>
<TR><TD>操作系统</TD><TD><%=BrowsCap.Platform%></TD></TR>
<TR><TD>是否支持VBScript</TD><TD><%=BrowsCap.vbscript%></TD></TR>
</TABLE>
<%Set BrowsCap = Nothing%>
</BODY>
</HTML>
注意：在本例中我们也接触了Server对象的CreateObject方法，Server.CreateObject用于创建已经注册到服务器上的ActiveX组件（说明：还有其他方法可以创建组件）。不过别忘了用"Set 对象 = Nothing"来及时释放资源，这应该成为一个习惯。

二、 File Access组件
File Access组件由FileSystemObject对象和TextStream对象组成，使用FileSystemObject对象，可以建立、检索、删除目录及文件，而TextStream对象则提供读写文件的功能。
实例wuf23.asp。强调：只有通过实践才能加深理解，实践和比较程序运行结果是快速掌握编程技巧的最好方法。
<%@ Language=VBScript %>
<% Option Explicit
' 注意绝对路径: C:\Inetpub\home\asp\wuf23.asp 主页路径: C:\Inetpub\home
Dim Path, File, FSO, CTF, Str, StrHTML, StrNoHTML

'使用 CreateObject 方法创建 FileSystemObject 对象 FSO
Set FSO = Server.CreateObject("Scripting.FileSystemObject")

Path = Server.MapPath("test") '返回test的物理目录(绝对路径)
'就本例而言, 下面这句与上面这句返回的Path完全一样
'Path = Server.MapPath("\asp\test\") 
Response.Write Path & "<Br>"

If FSO.FolderExists(Path) = false then '判断该文件夹是否存在
FSO.CreateFolder(Path) '新建文件夹
End If

File = Path & "\asptest.txt"
' 写文件操作
If FSO.FileExists(File) = True Then '判断该文件是否存在
'建立 TextStream 对象 CTF
Set CTF = FSO.OpenTextFile(File, 8, False, 0) '打开文件, 详见说明
Else
Set CTF = FSO.CreateTextFile(File,False, False) '新建文件
End If
CTF.Write "<P>第一个字符串; " '写字符串
CTF.WriteLine "第二个字符串; " '写字符串, 并加上一个换行符
CTF.Write "第三个字符串; "
CTF.Close '注意要关闭文件

' 读文件操作
Set CTF = FSO.OpenTextFile(File, 1,,0)
Do While CTF.AtEndOfStream <> True '判别是否文件结尾（循环语句）
Str = CTF.ReadLine '（每次）读取一行
StrNoHTML = StrNoHTML & Str & "<BR>" & VbCrLf 
StrHTML = StrHTML & Server.HTMLEncode(Str) & "<BR>" & VbCrLf
Loop
Response.Write StrNoHTML
Response.Write StrHTML

CTF.Close
Set CTF = Nothing '释放对象
Set FSO = Nothing
%>
CTF = FSO.OpenTextFile(File, 8, False, 0)，括号内第一个参数为文件名；第二个参数为8，表示在原文件后追加内容，若为1表示只读，为2则会重写原文件；第三个参数false表示，若指定文件不存在，也不新建文件，若为True，表示指定文件不存在，则新建该文件；第四个参数0表示以ASCII文件格式打开，若为-2，则表示以原来的格式打开。
CTF = FSO.CreateTextFile(File,False, False)，第二个参数false表示不覆盖已有文件，若为True，则表示覆盖（OverWrite）已有文件；第三个参数为False表示文件格式为ASCII，为True表示文件格式为Unicode。
Server对象的MapPath方法将指定的虚拟路径转换为真实的文件路径。MapPath将"/"和"\"字符视为相同。
Server对象的HTMLEncode方法允许你对特定的字符串进行HTML编码，或者说使浏览器中可以正确显示特定的字符。上例中，若未编码，则"<P>"显示不出来，而是被浏览器作为HTML标记，你可以对比一下运行结果。
实际上，File Access组件对文件、文件夹和驱动器的操作还是比较强大的，也提供了较多的方法，如果需要用到这方面的知识，别忘了使用它。
另外，到现在为止，写一个网页计数器已经是小菜一碟了吧，难怪那么多的网页提供免费计数器。怎么样？自己写一个图形计数器试试看，想怎么作弊就怎么作弊，完全自己说了算，爽呆！（小秘密：我的主页上有实例wuf24.asp）

三、 AD Rotator（广告翻转组件）
现在上网，恐怕最讨厌的是别人主页上的广告条，最喜欢的是自己主页上的广告条，广告条如同垃圾邮件一样，比比皆是，防不胜防。你也可以自己动手制造这样的垃圾，ASP的AD Rotator组件就可使每次打开或者重新加载网页时，随机的显示广告。这个例子包括三部分：
例程wuf25.asp
<%@ Language=VBScript %>
<% Option Explicit
Dim adr
'创建 AD Rotator 对象
Set adr = Server.CreateObject("MSWC.AdRotator")
adr.Border = 2 '指定图形文件的边框大小
adr.Clickable = True '指示显示的图片是否是一个超链接
adr.TargetFrame = "_blank" '设置超链接是否要指定Frame名称,如: _TOP _NEW _PARENT
'获取将要显示的图片及超链接设置 - 在文件 AdrSet.txt 中设置
Response.Write adr.GetAdvertisement("AdrSet.txt")
%>
AdrSet.txt内容（后面为注释，不是这个文件的内容）：
REDIRECT wuf26.asp 点击广告后，转由wuf26.asp来处理
WIDTH 468 广告图片宽度
HEIGHT 60 广告图片高度
* 分隔符
http://www.soyou.com/prog/ad/468x60_1.gif 广告图片所在位置，也可为本地图形文件
http://www.163.com/ 指向链接，若没有超链接，写入一个"-"
网易 文字说明
20 显示该广告的相对权重，即显示频率
http://fp.cache.imgis.com/images/Ad173962St1Sz1Sq1Id2.gif
http://www.sina.com.cn/
新浪网
30
http://61.139.77.73/images/canon.gif 也可以使用本地图片，如../images/flag.gif
http://www.canon.com.cn/
佳能
50
本例中一共有三个图片（图片大小468X60）及链接，每个链接的描述占四行，实际使用时，你可如法炮制，增加更多的图片。
<% 'wuf26.asp
URL = Request.QueryString("url")
Response.Redirect(URL) 
%>
wuf26.asp是一个最简单的处理程序，你可根据实际需要在这里加入更多的代码。
运行一下，原来这个组件的使用也很简单，你要做的就是得到自己的AdrSet.txt文件。利用这个组件，你甚至可以设计一个现在已非常时髦的广告交换主页。

四、 Content Linking组件
显然这个组件与链接有关系，如果想马上知道这个组件的具体用途，恐怕还操之过急，不妨先引用一个经典的例子：假设在网上阅读一本书，你对以下这些链接一定不会陌生：第1章、第2章、…、上一章、下一章（或前一页、后一页）等等。我们现在要做的就是如何在这些链接之间方便快速地设置跳转。
首先建一个链接列表文本文件，如urllist.txt
wuf23.asp 第1章：文件操作（File Access组件）
wuf28.asp 第2章：Content Linking组件使用示例
wuf22.asp 第3章：浏览器能力组件
链接url地址和描述之间用 Tab 键分隔。下面wuf27.asp用来列出urllist.txt中的所有链接。
<% @LANGUAGE = VBScript %>
<% Option Explicit %>
<html><head><title>Content Linking组件使用</title></head>
<body> 
<h2>目录列表: 注意核心链接是第2章, 你一定要点击它</h2>
<ul>
<%
Dim NextLink, Count
'建立 Content Linking 组件
Set NextLink = Server.CreateObject("MSWC.NextLink")

'获取文件 urllist.txt 中链接数目
Count = NextLink.GetListCount("urllist.txt")

Dim url, Dscr, I
For I = 1 To Count
url = NextLink.GetNthURL ("urllist.txt", I) '取得超链接
Dscr = NextLink.GetNthDescription ("urllist.txt", I) '取得文字描述
Response.Write "<li><a href = """ & url & """>" & Dscr & "</a>" & vbcrlf
Next
%> 
</ul></body></html>
然后，以wuf28.asp为例说明如何自动实现上一章和下一章跳转。
<% @LANGUAGE = VBScript %>
<% Option Explicit %>
<html><head><title>这个链接要注意</title></head>
<body>

<p>这里是第 2 章的正文............</p>

<% '每个文件都包含下面这句, 就实现了自动链接%>
<!--#include file="wuf29.asp"-->
</body></html>
这里最后一句加上去就可以实现自动跳转，核心在wuf29.asp中。
<%
Dim NextLink, rank
Set NextLink = Server.CreateObject ("MSWC.NextLink")
'当前的链接在 urllist.txt 中位于第几个
rank = NextLink.GetListIndex ("urllist.txt")
Response.Write "<hr>"

If (rank > 1) Then 'rank = 1 不存在前一页
Response.Write "|<a href=""" & NextLink.GetPreviousURL("urllist.txt") & """>上一章</a>|"
End If

If (rank < NextLink.GetListCount("urllist.txt")) Then 'rank在最后, 则没有下一页
Response.Write "|<a href=""" & NextLink.GetNextURL("urllist.txt") & """>下一章</a>|"
End If
%>
运行这个例子后，你马上能真正理解这个组件的作用，简而言之，就是不需要在每页都写一个"上一章"、"下一章"，完全通过wuf29.asp一下搞定，是不是很方便？！不然你要是手工修改链接的话，不是太麻烦了几点吗？
现在你应该明白了，网上大量的免费计数器、免费留言板、免费聊天室、广告交换网等等……，其原理都不过如此，大可不必崇拜。

赞 (0)

相关推荐

  • ASP.net基础知识之常见错误分析

    1:command调用存储过程的时候,如果输出是dataset,selectcommand的command对象的connection先要指出,否则catch一辈子也是空的.. 2:存储过程的varchar字段如果是x.x的这种格式,容易出现细微的傻错误,注意不要漏了[]. 3:如果ascx文件的默认服务器控件的事件不重写的话在control控件里面没有自动回送!切记. 4:Page.RegisterOnSubmitStatement在ascx文件中小心使用... 5:viewstate在true

  • asp知识整理笔记1（问答模式）

    近来有很多的读者向我们咨询学习ASP的方法和在学习中遇到的一些问题,其中有一些是初学者经常遇到和面临的问题.为了让读者在学习ASP的过程中加深对ASP的了解,并能够有效地解决遇到的问题,我们特别收集了比较有代表性的一些问题,在此列举出来并一一给予解答,希望能在这有限的篇幅里为你学习ASP助一臂之力. 问题1:ASP是一种编程语言吗? 答:ASP不是编程语言,而是一种开发环境.ASP提供了一个在服务器端执行指令的环境,它利用了特殊的符号()来区分HTML与必须经过服务器翻译才能送往客户端的命令.它

  • ASP.NET母版页基础知识介绍

    ASP.NET母版页基础知识介绍

    模板页是做什么的? 利用模板页可以方便快捷的创建统一风格的ASP.NET网站,并且容易管理和维护,提高了效率. 模板页为网页定义所需要的外观和标准,在母版的基础上创建包含显示内容的各个内容页.当用户请求内容页时,这些内容页与母版页合并,这样,模板页的布局与内容页的布局就可以组合在一起输出了. 模板页一般用来: 1.通过修改模板页来处理网页的通用功能. 2.可以方便的创建一组控件和代码,并应用于一组网页. 3.通过允许控制占位符控件的呈现方式,模板页可以在细节上控制最终页的布局. 模板页与普通页

  • asp知识整理笔记2（问答模式）

    问题9:我有没有必要在每一个ASP文件中使用"Option Explicit"? 答:在实际应用中,VBscript变量的概念已经模糊了,允许直接使用变量,而不用Dim声明变量,但这并不是一个好习惯,容易造成程序错误,因为可能重复定义一个变量.我们可以在程序中使用Option Explicit语句,这样在使用一个变量的时候,必须先声明它,如果使用了没有经过声明的变量,运行时,程序就会出错. 实践证明,ASP文件中使用"Option Explicit"可以使得程序出错

  • asp知识整理笔记4（问答模式）

    继前几篇篇<asp知识整理笔记1>和<asp知识整理笔记2>,<asp知识整理笔记3>新鲜出炉: 23.问题:在ASP文件中读取HTML的表单字段有几种方法? 答:Request对象除了可以用来读取附带在网址后面的参数以外,也可以读取HTML表单字段的内容,经常使用的语法结构如下: < Form name =Formname method="Get|Post"Action="URL">< Form > 其中

  • 讲解ASP方面的知识比较全的asp学习教程

    讲解ASP方面的知识比较全!适合 刚开始学习ASP的朋友们 给我加分!!!!   第一部分  安装Active Server  Page的准备工作   .第一章 安装和使用   WINDOWS NT Server    ............  .第二章 安装和使用   IIS    ............  .第三章 安装和使用   SQL Server    ............  .第四章 Exchage   Active Server,    Index Server和   Ne

  • 服务器XMLHTTP(Server XMLHTTP in ASP)基础知识

    相对于 Ajax,服务端 XMLHTTP 就是在服务端使用 XMLHttpRequest 对象了.虽然说,在服务端使用异步请求是比较不方便的,但是做为可以服务端发送 HTTP 请求的组件,学习一下也是没有坏处的. 这里,我讲的是在 ASP 环境中使用服务端 XMLHttpRequest,并以 JScript 做为演示代码的语言,因此,你需要了解 ASP 以及 JScript. 服务端 XMLHTTP,通常会用在获取远程主机的网页或者其他内容,新闻聚合系统一般就是使用服务端 XMLHTTP 对象来

  • ASP.NET 2.0 程序安全的基础知识

    成员关系的概念在人类社会中是一个层次比较低的概念,源于希望属于某个群组的意识.我们希望能觉得自己是某个团队的一部分,让别人知道我们是谁,因此Web搭上这个流行趋势,采用这个概念只是时间早晚的问题.如果坐下来想一想曾经登录过多少个站点并在这些站点上保存了简单的用户信息,可能会发现自己所属的群组比一开始想象的要多得多.从出售书籍和小器具的站点到讨论拥有一辆Ford Puma的好处的社区,或者宣传一个名为Look Around You的BBC TV喜剧节目的站点,作者发现自己是会员的站点多得无法一一列

  • ASP知识讲座四

    ASP内置组件 前三讲中,我们主要介绍了ASP提供的四大内置对象:l Response对象:向浏览器发送信息.l Request对象:访问从浏览器发送到服务器的信息(如获取表单数据).l Session对象:存储.读取特定用户对话信息.l Application对象:存储.读取所有用户共享的应用程序信息.此外还有Server对象和ObjectContext对象我们将在以后的实例中学习(提示:其实不经意之间你已经可以利用所学知识编写网上聊天室了).本讲的内容是使用ASP的ActiveX Serve

  • asp知识整理笔记3（问答模式）

    继上两篇<asp知识整理笔记1>和<asp知识整理笔记2>,<asp知识整理笔记3>新鲜出炉: 17.问题:在ASP中使用ADO的AddNew方法和直接使用"Insert into..."语句有何不同?哪种方式更好? 答:ADO的AddNew方法只是将"Insert into "语句封装了起来,所以,当对大量数据进行操作的时候,直接使用SQL语句将会大大加快存取数据的速度,因为它减少了ADO的"翻译"时间,由于

  • javascript asp教程第四课 同时使用vbscript和javascript

    开始: 你能让javascript和vbscript实现从同一个表格里传出音乐.看看下面的脚本: function JSGreeting() { return "Greetings from a JavaScript Function"; } Function VBGreeting() VBGreeting="Greetings from a VBScript Function" End Function Function toDollars(x) toDollar

  • 网络基础知识讲座之四理解数据链路层

    2层是数据链路层,是以太网所在的层.在这一层我们将讨论网桥.交换和虚拟局域网,要让一个网络运行起来,你实际上不需要学习以太网内部的工作原理,当然,如果你愿意学习的话,你可以利用其它的时间学习这方面的知识. 以太网交换机是一种"网桥"设备.传统的网桥是这样工作的,一开始它接收以太网帧,然后,把它们发送到除接收端口之外的全部其它端口.以太网交换机具允许允许双绞线连接的能力.它渐学习哪一个端口连接了哪 些MAC地址.这时候,网桥就变成了一台学习设备,能够存储在一个端口上看到的全部的MAC地址

  • ASP.NET MVC页面重定向简单介绍

    在asp.net中页面重定向:Server.Execute("m2.aspx"); 服务器保存此页转向前的数据后,使页面转向到m2.aspx执行, 再返回本页继续执行.再将三者结果合并后返回给浏览器. 以上都是服务器端页面转向所以浏览器不出现页更改记录(显示的地址不会改变).因此,如果用户刷新此页,也许会出现一些其它意外情况. 此类页转向,可完成一些其它功能,比如访问到前一页面中的服务端控件. 一.Response.Redirect: 当浏览器请求aspx页面时,碰到Redirect(

  • ASP.NET 重定向的几种方法小结

    一.Transfer Execute Redirect重定向方法介绍 1.Server.Transfer方法: Server.Transfer("m2.aspx");//页面转向(服务器上执行).服务器停止解析本页,保存此页转向前的数据后,再使页面转向到m2.aspx, 并将转向前数据加上m2.aspx页结果返回给浏览器. 2.Server.Execute方法: Server.Execute("m2.aspx"); 服务器保存此页转向前的数据后,使页面转向到m2.a

随机推荐