swift语言AutoreleasePool原理及使用场景

目录
  • 使用场景
    • NSAutoreleasePool
    • @autoreleasepool
    • __autoreleasing
  • 源码分析
    • __AtAutoreleasePool结构体
    • AutoreleasePoolPage
    • POOL_BOUNDARY
  • 多层嵌套
    • push
    • autoreleaseFast
    • autoreleaseFullPage
    • autoreleaseNoPage
    • add
    • pop
    • popPage
    • releaseUntil
    • autorelease
    • hotPage
    • coldPage
  • 调试
    • _objc_autoreleasePoolPrint
  • UIApplicationMain
  • 释放时机
    • 区分
    • runloop

使用场景

ARC下,AutoreleasePool主要应用在大量创建临时对象的场景,通过AutoreleasePool控制内存峰值,是一个很好的选择。

NSAutoreleasePool

MRC可以调用NSAutoreleasePool使对象延迟释放,在ARC下这个API已经被禁用。

NSAutoreleasePool *pool = [[NSAutoreleasePool alloc] init];
// ...
[pool release];

@autoreleasepool

除了NSAutoreleasePool还可以使用@autoreleasepool,并且苹果推荐使用@autoreleasepool,因为这个API性能更好,在ARC下依然可以使用@autoreleasepool

无论是MRC还是ARCautorelease最大的作用,是在大量创建对象的同时,通过修饰让内存得到提前释放,从而降低内存峰值。

@autoreleasepool {
    NSMutableArray *channelItemsJSONArray = [NSMutableArray arrayWithContentsOfFile:[self cachedChannelItemsFile]];
    NSArray *items = [self channelItemsJSONArray];
    if (![items writeToFile:[self cachedChannelItemsFile] atomically:YES]) {
        [channelItemsJSONArray writeToFile:[self cachedChannelItemsFile] atomically:YES];
    }
    items = nil;
}

__autoreleasing

ARC下,需要被自动释放的对象,可以用__autoreleasing修饰,让对象延迟释放。

+ (NSArray *)parseString:(NSString *)originalM3U8Str m3u8Host:(NSString *)m3u8url error:(NSError *__autoreleasing *)errorPtr;

源码分析

__AtAutoreleasePool结构体

struct __AtAutoreleasePool {
    __AtAutoreleasePool() {
        atautoreleasepoolobj = objc_autoreleasePoolPush();
    }
    ~__AtAutoreleasePool() {
        objc_autoreleasePoolPop(atautoreleasepoolobj);
    }
    void * atautoreleasepoolobj;
};

@autoreleasepool本质上会被系统转换成C++__AtAutoreleasePool结构体,@autoreleasepool的大括号开始,对应着objc_autoreleasePoolPush函数。大括号结束,对应着objc_autoreleasePoolPop函数。通过clang命令将OC代码转成C++代码,可以看到有一个__AtAutoreleasePool结构体。

__AtAutoreleasePool结构体在创建的时候会执行objc_autoreleasePoolPush函数,在释放的时候会执行析构函数,并执行objc_autoreleasePoolPop函数。在这两个函数内部,会调用AutoreleasePoolPagepushpop函数。

AutoreleasePoolPage

在运行时代码中,objc_autoreleasePoolPopobjc_autoreleasePoolPush,都调用了AutoreleasePoolPage类的实现。

void *
objc_autoreleasePoolPush(void)
{
    return AutoreleasePoolPage::push();
}
void
objc_autoreleasePoolPop(void *ctxt)
{
    AutoreleasePoolPage::pop(ctxt);
}

AutoreleasePoolPage的定义中,可以看到有parentchild的定义,当page中对象太多存储不下时,会创建其他的page对象来存储,AutoreleasePoolPage的结构是一个双向链表。在插入新的autorelease对象时,也会从链表头向后查找,直到找到未满的page

class AutoreleasePoolPage
{
    magic_t const magic;                // 校验page的结构是否完整
    id *next;                           // 指向下一个可以存放autorelease对象的地址
    pthread_t const thread;             // 当前所在的线程
    AutoreleasePoolPage * const parent; // 当前page的父节点
    AutoreleasePoolPage *child;         // 当前page的子节点
    uint32_t const depth;               // page的深度
    uint32_t hiwat;
}

AutoreleasePoolPage是一个C++的类,每个page4096个字节,也就是16进制的0x1000,也就是4kb的空间。这些空间中,其自身的成员变量只占56个字节,也就是下面七个成员变量,每个占8字节,总共56个字节。其他的四千多个字节,都用来存放被autorelease修饰的对象内存地址。

POOL_BOUNDARY

POOL_BOUNDARY的作用是,区分不同的自动释放池,也就是不同的@autoreleasepool。调用push时,会传入POOL_BOUNDARY并返回一个地址例如0x10380x1038是不存储@autorelease对象的地址的,起到一个标识作用,用来分割不同的@autoreleasepool

调用pop时,会传入end的地址,并从后到前调用对象的release方法,直到POOL_BOUNDARY为止。如果存在多个page,会从childpage的最末尾开始调用,直到POOL_BOUNDARYpage的结构是一个栈结构,释放的时候也是从栈顶开始释放。

next指针指向栈顶,是栈里面很常见的一个设计。AutoreleasePoolPagePOOL_BOUNDARY的区别在于,AutoreleasePoolPage负责维护存储区域,而POOL_BOUNDARY则负责分割存储在page中的对象地址,以@autoreleasepool为单位进行分割。

多层嵌套

@autoreleasepool {
    NSObject *p1 = [[NSObject alloc] init];
    NSObject *p2 = [[NSObject alloc] init];
    @autoreleasepool {
        NSObject *p3 = [[NSObject alloc] init];
        @autoreleasepool {
            NSObject *p4 = [[NSObject alloc] init];
        }
    }
}

如果是多层@autoreleasepool的嵌套,会用同一个AutoreleasePoolPage对象。以下面的三个嵌套为例,在同一个page中的顺序是下图这样。不同的@autoreleasepoolPOOL_BOUNDARY做分割。

push

创建一个autoreleasePool之后,就会调用push函数。在push函数中会判断是否调试模式下,如果调试模式会每次生成一个新的pagedebug环境代码可以直接忽略,只保留autoreleaseFast函数。

static inline void *push()
{
    id *dest;
    if (DebugPoolAllocation) {
        dest = autoreleaseNewPage(POOL_BOUNDARY);
    } else {
        dest = autoreleaseFast(POOL_BOUNDARY);
    }
    return dest;
}

autoreleaseFast

在函数内部,会通过hotPage获取当前的pagehotPage函数内部本质上是一个pagekey的映射。

  • 如果page不为空并且有空间,则调用pageadd函数将对象添加到page中,并将POOL_BOUNDARY添加在当前的位置。
  • 如果page已经被创建但没有空间,会调用autoreleaseFullPage函数创建新的page,并且将链表的末尾指向新创建的page
  • 如果没有创建page,则调用autoreleaseNoPage函数创建一个新的page,并且将当前线程的hotPage设置为新创建的page
static inline id *autoreleaseFast(id obj)
{
    AutoreleasePoolPage *page = hotPage();
    if (page && !page->full()) {
        return page->add(obj);
    } else if (page) {
        return autoreleaseFullPage(obj, page);
    } else {
        return autoreleaseNoPage(obj);
    }
}

autoreleaseFullPage

  • autoreleaseFullPage函数中,会从page的链表中,从前往后找到末尾的节点。
  • 创建一个新的page,在创建函数AutoreleasePoolPage中会处理parentchild指针的问题,返回的page可以直接用。
  • 调用setHotPagepage设置到哈希表中,并且调用pageadd函数将autorelease修饰的对象,添加到page中。
static __attribute__((noinline))
id *autoreleaseFullPage(id obj, AutoreleasePoolPage *page)
{
    do {
        if (page->child) page = page->child;
        else page = new AutoreleasePoolPage(page);
    } while (page->full());
    setHotPage(page);
    return page->add(obj);
}

autoreleaseNoPage

autoreleaseNoPage函数的核心代码比较简单,就是创建一个新的page,随后设置POOL_BOUNDARY标志,并且把对象添加进去。在函数中需要留意POOL_BOUNDARY标志,很多地方都用来做page是否为空的判断。

static __attribute__((noinline))
id *autoreleaseNoPage(id obj)
{
    AutoreleasePoolPage *page = new AutoreleasePoolPage(nil);
    setHotPage(page);
    if (pushExtraBoundary) {
        page->add(POOL_BOUNDARY);
    }
    return page->add(obj);
}

add

add函数比较简单,核心逻辑就是将obj放入next指针的位置,并且对next指针进行++,指向下一个位置。*next++表示先用后加,先将obj存入next的地址,随后+1

id *add(id obj)
{
    ASSERT(!full());
    unprotect();
    id *ret = next;
    *next++ = obj;
    protect();
    return ret;
}

pop

调用pop函数时,有三步处理。

  • 判断autoreleasepool是否为空,通过EMPTY_POOL_PLACEHOLDER占位符判断,为空则清空这个page
  • 传入的stop是否不等于POOL_BOUNDARY标识,如果不等于则可能是一个有问题的page
  • 调用popPage方法,释放对象。
static inline void
pop(void *token)
{
    AutoreleasePoolPage *page;
    id *stop;
    // 1.
    if (token == (void*)EMPTY_POOL_PLACEHOLDER) {
        page = hotPage();
        if (!page) {
            return setHotPage(nil);
        }
        page = coldPage();
        token = page->begin();
    } else {
        page = pageForPointer(token);
    }
    // 2.
    stop = (id *)token;
    if (*stop != POOL_BOUNDARY) {
        if (stop == page->begin()  &&  !page->parent) {
        } else {
            return badPop(token);
        }
    }
    // 3.
    return popPage<false>(token, page, stop);
}

popPage

popPage函数核心代码就是调用releaseUntil函数,在最开始会调用releaseUntil函数去完成释放操作。

按照page达到一半就扩容的原则,后面的if语句会判断执行poppage链表的状态。

如果少于半满,就将子节点删除。

如果大于半满,则保留子节点,并删除后面的节点。

static void
popPage(void *token, AutoreleasePoolPage *page, id *stop)
{
    page->releaseUntil(stop);
    if (page->child) {
        if (page->lessThanHalfFull()) {
            page->child->kill();
        }
        else if (page->child->child) {
            page->child->child->kill();
        }
    }
}

releaseUntil

releaseUntil函数内部,核心逻辑是从当前page,从后到前调用objc_release,释放被autorelease修饰的对象。

  • 获取当前的hotPage
  • 判断page是否为空,如果为空则表示里面的对象被释放完,则将page的父节点page设置为hotPage
  • 获得上一个节点,->的算数优先级比--要高,所以是先通过next获取当前节点地址,这是一个为空的待存入节点,随后执行--操作获取上一个对象地址。
  • 通过memset将上一个节点释放。
  • 判断上一个节点是否占位符号POOL_BOUNDARY,如果不是则调用objc_release释放对象。
  • while循环结束后,将当前page设置为hotPage
void releaseUntil(id *stop)
{
    while (this->next != stop) {
        AutoreleasePoolPage *page = hotPage();
        while (page->empty()) {
            page = page->parent;
            setHotPage(page);
        }
        page->unprotect();
        id obj = *--page->next;
        memset((void*)page->next, SCRIBBLE, sizeof(*page->next));
        page->protect();
        if (obj != POOL_BOUNDARY) {
            objc_release(obj);
        }
    }
    setHotPage(this);
}

autorelease

对象调用autorelease方法会被编译器转换为objc_autoreleaseReturnValue方法,并且经过多层调用,会来到底层的autorelease函数。

在这个函数中会判断传入的对象是否tagged pointer,因为tagged pointer没有引用计数的概念。随后会调用autoreleaseFast函数,函数内部调用add函数将obj对象加入到page中,并且会判断是否需要创建新的page

static inline id autorelease(id obj)
{
    assert(!obj->isTaggedPointer());
    id *dest __unused = autoreleaseFast(obj);
    return obj;
}

hotPage

hotPage可以被理解为,page链表的末尾,也就是调用push函数被插入的位置。执行hotPage函数获取,以及调用setHotPage设置,都是操作的链表的末尾page

AutoreleasePoolPage对象和线程一一对应,并且都被存储在tls的哈希表中。通过tls_get_direct函数并传入key可以获取到对应的自动释放池。

static inline AutoreleasePoolPage *hotPage()
{
    AutoreleasePoolPage *result = (AutoreleasePoolPage *)
        tls_get_direct(key);
    if ((id *)result == EMPTY_POOL_PLACEHOLDER) return nil;
    if (result) result->fastcheck();
    return result;
}

hotPage函数中的判断是下面的定义,这个标示意思是当前page为空,也就是从未存储过任何对象。是一个标志位,下面是标志位的定义。

# define EMPTY_POOL_PLACEHOLDER ((id*)1)

coldPage

coldPage只有获取函数,没有设置函数。这是因为coldPage函数本质上,就是寻找page链表的根节点,从源码中的while循环可以看到。

static inline AutoreleasePoolPage *coldPage()
{
    AutoreleasePoolPage *result = hotPage();
    if (result) {
        while (result->parent) {
            result = result->parent;
            result->fastcheck();
        }
    }
    return result;
}

调试

_objc_autoreleasePoolPrint

如果想调试自动释放池,可以通过_objc_autoreleasePoolPrint私有API来进行。将项目改为MRC,并且在命令行项目中增加下面这些调试代码。

int main(int argc, const char * argv[]) {
    _objc_autoreleasePoolPrint();     // print1
    @autoreleasepool {
        _objc_autoreleasePoolPrint(); // print2
        Person *p1 = [[[Person alloc] init] autorelease];
        Person *p2 = [[[Person alloc] init] autorelease];
        _objc_autoreleasePoolPrint(); // print3
    }
    _objc_autoreleasePoolPrint();     // print4
    return 0;
}

打印结果如下,可以看到POOL_BOUNDARYpage中也占了一个位置。

objc[68122]: ############## (print1)
objc[68122]: AUTORELEASE POOLS for thread 0x1000aa5c0
objc[68122]: 0 releases pending. // 当前自动释放池中没有任何对象
objc[68122]: [0x102802000]  ................  PAGE  (hot) (cold)
objc[68122]: ##############
objc[68122]: ############## (print2)
objc[68122]: AUTORELEASE POOLS for thread 0x1000aa5c0
objc[68122]: 1 releases pending. // 当前自动释放池中有1个对象,这个对象为POOL_BOUNDARY
objc[68122]: [0x102802000]  ................  PAGE  (hot) (cold)
objc[68122]: [0x102802038]  ################  POOL 0x102802038  //POOL_BOUNDARY
objc[68122]: ##############
objc[68122]: ############## (print3)
objc[68122]: AUTORELEASE POOLS for thread 0x1000aa5c0
objc[68122]: 3 releases pending. // 当前自动释放池中有3个对象
objc[68122]: [0x102802000]  ................  PAGE  (hot) (cold)
objc[68122]: [0x102802038]  ################  POOL 0x102802038  //POOL_BOUNDARY
objc[68122]: [0x102802040]       0x100704a10  HTPerson          //p1
objc[68122]: [0x102802048]       0x10075cc30  HTPerson          //p2
objc[68122]: ##############
objc[68156]: ############## (print4)
objc[68156]: AUTORELEASE POOLS for thread 0x1000aa5c0
objc[68156]: 0 releases pending. // 当前自动释放池中没有任何对象,因为@autoreleasepool作用域结束,调用pop方法释放了对象
objc[68156]: [0x100810000]  ................  PAGE  (hot) (cold)
objc[68156]: ##############

UIApplicationMain

项目中经常会看到下面的代码,很多人的解释是“这个autoreleasepool是为了释放主线程的autorelease对象的”。但是,这个说法是错误的。autoreleasepool只负责自己作用域中添加的对象,而主线程在运行过程中,也会隐式创建autoreleasepool对象,这个pool是包含在main函数的pool里面的。

所以,主线程runloop每次执行循环后,释放的对象是主线程的。而main函数的autoreleasepool释放的,是main函数中直接创建的对象。

int main(int argc, char * argv[]) {
    @autoreleasepool {
        return UIApplicationMain(argc, argv, nil, NSStringFromClass([AppDelegate class]));
    }
}

释放时机

区分

如果是在viewDidLoad方法中创建一个autorelease对象,并不是在这个方法结束后释放对象,这个说法是错误的。即便执行到viewDidAppear,依然不会释放对象。

autorelease修饰的对象,释放时机有两种。

  • 如果通过代码添加一个autoreleasepool,在作用域结束时,随着pool的释放,就会释放pool中的对象。这种情况是及时释放的,并不依赖于runloop
  • 另一种就是由系统自动进行释放,系统会在runloop开始的时候创建一个pool,结束的时候会对pool中的对象执行release操作。

runloop

如果是系统创建的pool,需要手动开启runloop,主线程默认已经开启并运行,子线程需要调用currentRunLoop方法开启并运行runloop,子线程中系统创建pool的流程才会正常工作。

包括主线程在内的每个线程,如果在线程中使用到了AutoreleasePool,则会创建两个Observer并添加到当前线程的Runloop中,通过这两个Observer进行对象的自动内存管理。

// activities = 0x1,kCFRunLoopEntry
<CFRunLoopObserver 0x60000012f000 [0x1135c2bb0]>{valid = Yes, activities = 0x1, repeats = Yes, order = -2147483647, callout = _wrapRunLoopWithAutoreleasePoolHandler (0x10eee6276)}
// activities = 0xa0,kCFRunLoopBeforeWaiting | kCFRunLoopExit
<CFRunLoopObserver 0x60000012ef60 [0x1135c2bb0]>{valid = Yes, activities = 0xa0, repeats = Yes, order = 2147483647, callout = _wrapRunLoopWithAutoreleasePoolHandler (0x10eee6276)}

首先会创建一个Observer并监听kCFRunLoopEntry消息,时机是在进入Runloop前,此Observer的优先级设置为-2147483647的最高优先级,以保证回调发生在Runloop其他事件前。

然后创建另一个Observer,并监听kCFRunLoopBeforeWaitingkCFRunLoopExit消息,时机分别在进入Runloop休眠和退出Runloop时,将Observer的优先级设置为2147483647,以保证回调发生在Runloop其他事件之后。

两个Observer都有相同的回调函数_wrapRunLoopWithAutoreleasePoolHandler,在第一次回调时会在内部调用_objc_autoreleasePoolPush函数,创建自动释放池。

kCFRunLoopBeforeWaiting将要进入休眠前,调用_objc_autoreleasePoolPop函数释放自动释放池中的对象,并调用_objc_autoreleasePoolPush函数创建一个新的释放池。在kCFRunLoopExit将要退出Runloop时调用_objc_autoreleasePoolPop函数,释放自动释放池中的对象。

以上就是swift语言AutoreleasePool原理及使用场景的详细内容,更多关于swift AutoreleasePool 原理的资料请关注我们其它相关文章!

时间: 2022-09-10

swift语言Codable 用法及原理详解

目录 Codable Codable 的用法 JSON 和 模型的相互转换 解码(JSON Data -> Model): 编码(Model -> JSON Data): Codable 支持的数据类型 基础数据类型 Date 嵌套对象 枚举 自定义 CodingKeys Codable 的原理 Decodable 协议 Container 核心原理分析(Container <--> JSON) JSONDecoder 的解码过程 编译器帮我们做了什么? 默认值问题 属性包装器 @

SwiftUI 引导页界面实现示例

目录 引言 页面分析-元素构成 实战编程-创建项目 实战编程-引导图片 实战编程-引导文字 实战编程-引导按钮 实战编程-轮博滚动 整体效果-预览 本章小结 引言 当用户首次启用App时,客户端应用常常会出现一段过渡的App功能说明页面,帮助用户快速了解并熟悉App的基本功能和亮点. 引导页是用户了解产品的第一个窗口,能给用户留下最初的印象. 一个好的引导页可以很好地传达产品设计理念和产品设计调性,也是企业传达企业文化很好的窗口.当然对于开发者来说,也是必不可少的练手项目. 接下来,我们同样将用

SwiftUI&nbsp;登录界面布局实现示例详解

目录 引言 页面分析-元素构成 实战编程-背景图片 实战编程-说明文字 实战编程-登录方式 实战编程-辅助文字 本章小结 引言 为了更好地了解和学习SwiftUI,我们快速学习SwiftUI的三种基本布局:HStack水平布局容器.VStack垂直布局容器.ZStack层叠布局容器. 在实际开发过程中,登录页面是移动端产品必不可少的页面,也是很好的练手项目. 接下来,我们将用10分钟来构建一个登录页面布局,以下面UI设计稿为例: 页面分析-元素构成 采用自顶向下的设计思想拆解UI设计稿的元素,可

LeetCode 题解 Swift 有效的完全平方数

目录 题目 方法一:使用内置的库函数 思路及解法 复杂度分析 方法二:暴力 思路及解法 代码 复杂度分析 方法三:二分查找 思路及解法 细节 代码 复杂度分析 题目 给定一个 正整数 num,编写一个函数,如果 num 是一个完全平方数,则返回 true,否则返回 false. 进阶:不要 使用任何内置的库函数,如 sqrt. 示例 1: 输入: num = 16 输出: true 示例 2: 输入: num = 14 输出: false 方法一:使用内置的库函数 思路及解法 根据完全平方数的性

LeetCode 刷题 Swift 两个数组的交集

目录 题目 方法一:两个集合 思路及解法 代码 复杂度分析 方法二:排序 + 双指针 思路及解法 代码 复杂度分析 题目 给定两个数组 nums1 和 nums2,返回 它们的交集 .输出结果中的每个元素一定是 唯一 的.我们可以 不考虑输出结果的顺序 . 示例 1: 输入: nums1 = [1,2,2,1], nums2 = [2,2] 输出: [2] 示例 2: 输入: nums1 = [4,9,5], nums2 = [9,4,9,8,4] 输出: [9,4] 解释: [4,9] 也是可

Swift使用SnapKit模仿Kingfisher第三方扩展优化

目录 正文 SnapKit扩展方式简要思考 Kingfisher扩展方式简要思考 自行模仿尝试 最后 正文 我们平时用swift写第三方扩展(OC中的分类)时,可能会直接就往扩展里面写方法,简单又方便,然而当我们看一些常用你的三方(例如:Kingfisher.SnapKit)等,都会用一个简单的参数引出(例如:kf.snp),下面来探索一下怎么用的,然后在总结其优缺点 SnapKit扩展方式简要思考 以 SnapKit为例,使用如下,发现引入了 snp var iv = UIImageView(

ThinkPHP5.0框架验证码功能实现方法【基于第三方扩展包】

本文实例讲述了ThinkPHP5.0框架验证码功能实现方法.分享给大家供大家参考,具体如下: 背景 ThinkPHP5.0 已经出现很久了,最近有所接触,下面介绍一下常用的第三方验证码功能的使用. ♜ 功能开发 1).引入第三方扩展包 进行 TP5 的开发,Composer 的使用会成为重要技能,以 windows 为例子,输入命令: composer require topthink/think-captcha 完成上述操作,会在以下目录中出现 captcha 的扩展包 ..\vendor\t

vscode 安装go第三方扩展包填坑记录的详细教程

1.vscode中安装go扩展包,不再阐述. 2.在安装好go的扩展包以后,创建GOPATH环境变量 3.PATH中会自动添加,如果没有可手动添加 4.在GOPATH目录下创建自己的工作空间(为什么一定是在GOPATH下创建,还不太清楚),我的是workspace(名称可以自定义) 5.打开VSCODE,文件-打开文件夹,选择GOPATH目录 6.在workspace下创建helloworld目录(我称为项目空间) 7.配置VSCODE中的setting.json文件 加入如下配置: 8.编写h

Swift 3.0基础学习之扩展

介绍 扩展可以为类,结构体,枚举和协议添加新的功能.包括可以对没有源码访问权限的类型进行扩展.扩展和 Objective-C 分类 的概念类似.(和 Objective-C 的分类不一样的是,Swift 扩展没有名称). 在 Swift 中,扩展可以做到: 添加计算的实例属性和计算的类型属性 定义实例方法和类型方法 提供新的初始化器 定义下标 定义并使用新的嵌套类型 使现有类型符合协议 值得注意的是:扩展可以为类型添加功能,但是不可以重写现有的功能. 扩展语法 使用关键字 extension 定

Swift 4最全的新特性详细解析(推荐)

引言 Swift,苹果于2014年WWDC(苹果开发者大会)发布的新开发语言,可与Objective-C共同运行于Mac OS和iOS平台,用于搭建基于苹果平台的应用程序.Swift吸收了众多现代编程语言的优点,尽力的提供简洁的编程语言和强大的功能. WWDC 2017 给大家带来了很多惊喜.Swift 4 也伴随着 Xcode 9 测试版来到了我们的面前,很多强大的新特性非常值得我们期待在正式项目中去使用它.因为 Swift 4 是开源的,如果你关注 swift-evolution 这个项目的

浅谈webpack 构建性能优化策略小结

背景 如今前端工程化的概念早已经深入人心,选择一款合适的编译和资源管理工具已经成为了所有前端工程中的标配,而在诸多的构建工具中,webpack以其丰富的功能和灵活的配置而深受业内吹捧,逐步取代了grunt和gulp成为大多数前端工程实践中的首选,React,Vue,Angular等诸多知名项目也都相继选用其作为官方构建工具,极受业内追捧.但是,随者工程开发的复杂程度和代码规模不断地增加,webpack暴露出来的各种性能问题也愈发明显,极大的影响着开发过程中的体验. 问题归纳 历经了多个web项目

PHP安全配置优化详解

由于脚本语言和早期版本设计的诸多原因,php项目存在不少安全隐患.从配置选项来看,可以做如下的优化. 1.屏蔽PHP错误输出. 在/etc/php.ini(默认配置文件位置),将如下配置值改为Off display_errors=Off 不要将错误堆栈信息直接输出到网页上,防止黑客加以利用相关信息. 正确的做法是: 把错误日志写到日志文件中,方便排查问题. 2.屏蔽PHP版本. 默认情况下PHP版本会被显示在返回头里,如: Response Headers X-powered-by: PHP/7

CI框架教程之优化验证码机制详解【验证码辅助函数】

本文实例讲述了CI框架教程之优化验证码机制.分享给大家供大家参考,具体如下: 验证码机制在CI框架中是通过一个辅助函数captcha()进行实现的--验证码辅助函数文件包含了一些帮助你创建验证码图片的函数.. 那么我们如何使用CI的captcha()辅助函数来完成验证码功能呢?下面我会先讲述如何使用CI的captcha()辅助函数来完成验证码功能,然后在讲述如何具体的对CI框架的验证码机制进行优化. 1.CI框架验证码功能的使用 a)  首先我们要先加载辅助函数 加载辅助函数一共有两种方法: ①

webpack优化的深入理解

前言 由于前端的快速发展,相关工具的发展速度也是相当迅猛,各大框架例如vue,react都有自己优秀的脚手架工具来帮助我们快速启动一个新项目,也正式因为这个原因,我们对于脚手架中最关键的一环webpack相关的优化知之甚少,脚手架基本上已经为我们做好了相关的开发准备,但是当我们想要做一些定制化的优化操作时,对webpack的优化也需要有一定的了解,否则无从下手,接下来就让我们进入webpack的优化世界 构建速度提升 loader提升 loader是webpack中最重要的特性,由于webpac

VSCode配置Go插件和第三方拓展包的详细教程

前言 VSCode现在已经发展的相当完善,很多语言都比较推荐使用其来编写,Go语言也一样,前提你电脑已经有了Go环境和最新版本的VSCode 插件安装 直接在拓展插件中搜索Go,就可以安装Go插件 安装之后vscode会弹出该插件还需安装一些扩展工具支持,但是这些工具往往会下载失败,或者仅仅成功一部分 比如: Installing github.com/nsf/gocode FAILED Installing github.com/uudashr/gopkgs/cmd/gopkgs FAILED